prg.cuh

Go to the documentation of this file.

// SPDX-License-Identifier: Apache-2.0
 
#pragma once
#include <cuda_runtime.h>
#include <cuda/std/array>
#include <concepts>
#include <cuda/std/span>

template <typename Prg, int mul>
concept Prgable = requires(Prg prg, int4 seed) {
  { prg.Gen(seed) } -> std::same_as<cuda::std::array<int4, mul>>;
};

template <typename Prg, int mul>
concept HasGenHalf = mul > 0 && mul % 2 == 0 && Prgable<Prg, mul> && requires(Prg prg, int4 seed, bool right) {
  { prg.GenHalf(seed, right) } -> std::same_as<cuda::std::array<int4, mul / 2>>;
};

template <typename Prg, int mul>
concept HasGen8 = Prgable<Prg, mul> && requires(Prg prg, cuda::std::span<const int4, 8> seeds) {
  { prg.Gen8(seeds) } -> std::same_as<cuda::std::array<cuda::std::array<int4, mul>, 8>>;
};
 
// -----------------------------------------------------------------------------
 
namespace fss::detail {
 
template <int mul, typename Prg>
  requires(mul > 0 && mul % 2 == 0 && Prgable<Prg, mul>)
__host__ __device__ inline cuda::std::array<int4, mul / 2> GenHalf(Prg &prg, int4 seed, bool right) {
  if constexpr (HasGenHalf<Prg, mul>) {
    return prg.GenHalf(seed, right);
  } else {
    auto full = prg.Gen(seed);
    cuda::std::array<int4, mul / 2> out{};
    int offset = right ? mul / 2 : 0;
    for (int i = 0; i < mul / 2; ++i) out[i] = full[i + offset];
    return out;
  }
}
 
// Keep the optional batched entry point outside the public PRG requirement.
template <int mul, typename Prg>
cuda::std::array<cuda::std::array<int4, mul>, 8> GenBatch(Prg &prg, cuda::std::span<const int4, 8> seeds) {
  if constexpr (HasGen8<Prg, mul>) {
    return prg.Gen8(seeds);
  } else {
    cuda::std::array<cuda::std::array<int4, mul>, 8> out{};
    for (int j = 0; j < 8; ++j) out[j] = prg.Gen(seeds[j]);
    return out;
  }
}
 
}  // namespace fss::detail